RouterOS 简单调优

add action=dst-nat chain=dstnat protocol=tcp dst-port=9090 in-interface=pppoe-out1 to-addresses=10.1.1.6 to-ports=9090 comment=test-nat

/system/script/add name=test source="/tool wol interface=ether1 mac=xx:xx:xx:xx:xx:xx"

/queue/simple/add name=test target=10.1.1.127 max-limit=1M/10M

# Cloudflare Dynamic DNS update script
# Required policy: read, write, test, policy
# Add this script to scheduler
# Install DigiCert root CA or disable check-certificate
# Configuration ---------------------------------------------------------------------

:local TOKEN "_TOKEN_"
:local ZONEID "_ZONEID_"
:local RECORDID "_RECORDID_"
:local RECORDNAME "_RECORDNAME_"
:local WANIF "pppoe-out1"

#------------------------------------------------------------------------------------

:global IP4NEW
:global IP4CUR

:local url "https://api.cloudflare.com/client/v4/zones/$ZONEID/dns_records/$RECORDID/"

:if ([/interface get $WANIF value-name=running]) do={
# Get the current public IP
    :local requestip [/tool fetch url="http://ifconfig.io/ip" mode=http output=user as-value]
    :set IP4NEW [:pick ($requestip->"data") 0 ([:len ($requestip->"data")]-1)]
# Check if IP has changed
    :if ($IP4NEW != $IP4CUR) do={
        :log info "CF-DDNS: Public IP changed to $IP4NEW, updating"
        :local cfapi [/tool fetch http-method=put mode=https url=$url check-certificate=yes output=user as-value \
            http-header-field="Authorization: Bearer $TOKEN,Content-Type: application/json" \
            http-data="{\"type\":\"A\",\"name\":\"$RECORDNAME\",\"content\":\"$IP4NEW\",\"ttl\":1,\"proxied\":false}"]
        :set IP4CUR $IP4NEW
        :log info "CF-DDNS: Host $RECORDNAME updated with IP $IP4CUR"
    }  else={
        :log info "CF-DDNS: Previous IP $IP4NEW not changed, quitting"
    }
} else={
    :log info "CF-DDNS: $WANIF is not currently running, quitting"
}

/system/scheduler/add name=ddns-scheduler interval=00:05:00 on-event=ddns